// 
// from processing.unlekker.net
//

Particle gas[];
int num;
int colors[][],colNum,colBG;
boolean doSaveFrame=false,doSetBackground=true;
float rotOffs=4,speed=1;
float centerX,centerY;

void setup() {
  size(600,400);
  num=30;
  smooth();
//  rectMode(CENTER_RADIUS);
  
  colors=new int[100][3];
  addColor(255,255,255);
  addColor(255,0,0);
  addColor(150,30,0);  
  addColor(255,200,0);
  addColor(0,200,255);
  addColor(0,20,50);
  addColor(0,200,50);
  
  colBG=((int)random(10000))%colNum;
  
  centerX=width/2+random(200)-100;
  centerY=height/2+random(150)-75;
  gas=new Particle[num];
  for(int i=0; i<num; i++) gas[i]=new Particle();
}

void loop() {
  if(doSetBackground) {
    background(colors[colBG][0],
      colors[colBG][1],
      colors[colBG][2]);
    doSetBackground=false;
  }
    
  noStroke();
  for(int i=0; i<num; i++) gas[i].update();
  
  if(doSaveFrame) {
    saveFrame();
    doSaveFrame=false;
  }
}

void addColor(int r,int g, int b) {
  colors[colNum][0]=r;
  colors[colNum][1]=g;
  colors[colNum][2]=b;
  colNum++;
}

void mouseMoved() {
  rotOffs=(float)mouseX/(float)width;
  rotOffs=rotOffs*3+4;
  speed=(float)mouseY/(float)height;
  speed=speed*2.9+0.1;
    
}

void mousePressed() {
  colBG=(colBG+1)%colNum;
  doSetBackground=true;
    
  centerX=width/2+random(200)-100;
  centerY=height/2+random(200)-100;
  for(int i=0; i<num; i++) gas[i].init();
}

void keyPressed() {
  if(key=='s') doSaveFrame=true;
}


class Particle {
  Vec2D v,dir;
  int col,age;
  float rad;
  
  Particle() {
    v=new Vec2D(0,0);
    dir=new Vec2D(0,0);
    init();
  }

  void init() {
    v.set(50,0);
    v.rotate(random(PI*2));
    v.add(centerX,centerY);
    dir.set(random(2)+0.15,0);
    dir.rotate(random(PI*2));

    do {
      col=((int)random(10000))%colNum;
    } while(col==colBG); 
    
    age=(int)random(100)+500;
    if(random(100)<70) rad=2;
    else rad=3+random(5);    
  }

  void update() {
    dir.rotate(radians(random(8)-rotOffs));
    v.add(dir.x*speed,dir.y*speed);
    age--;
    if(v.x<0 || v.x>width || v.y<0 || v.y>height 
      || age==0) init();
      
    fill(colors[col][0],colors[col][1],colors[col][2], 240);
    rect(v.x,v.y, rad,rad);

  }
    
}

// Vec2D - simple 2D vector class
// processing.unlekker.net

class Vec2D {
  float x,y;

  Vec2D(float _x,float _y) {
    x=_x;
    y=_y;
  }

  Vec2D(Vec2D v) {
    x=v.x;
    y=v.y;
  }

  void set(float _x,float _y) {
    x=_x;
    y=_y;
  }

  void set(Vec2D v) {
    x=v.x;
    y=v.y;
  }

  void add(float _x,float _y) {
    x+=_x;
    y+=_y;
  }

  void add(Vec2D v) {
    x+=v.x;
    y+=v.y;
  }

  void sub(float _x,float _y) {
    x-=_x;
    y-=_y;
  }

  void sub(Vec2D v) {
    x-=v.x;
    y-=v.y;
  }

  void mult(float m) {
    x*=m;
    y*=m;
  }

  void div(float m) {
    x/=m;
    y/=m;
  }

  float length() {
    return sqrt(x*x+y*y);
  }

  float angle() {
    return atan2(y,x);
  }

  void normalise() {
    float l=length();
    if(l!=0) {
      x/=l;
      y/=l;
    }
  }

  Vec2D tangent() {
    return new Vec2D(-y,x);
  }

  void rotate(float val) {
    // Floats are not precise enough, so doubles are used for the calculations
    double cosval=Math.cos(val);
    double sinval=Math.sin(val);
    double tmpx=x*cosval - y*sinval;
    double tmpy=x*sinval + y*cosval;

    x=(float)tmpx;
    y=(float)tmpy;
  }
}